1015: [JSOI2008]星球大战starwar

1015: [JSOI2008]星球大战starwar

Time Limit: 3 Sec  Memory Limit: 162 MB
Submit: 3001  Solved: 1321
[Submit][Status]

Description

很久以前，在一个遥远的星系，一个黑暗的帝国靠着它的超级武器统治者整个星系。某一天，凭着一个偶然的机遇，一支反抗军摧毁了帝国的超级武器，并攻下了星系中几乎所有的星球。这些星球通过特殊的以太隧道互相直接或间接地连接。 但好景不长，很快帝国又重新造出了他的超级武器。凭借这超级武器的力量，帝国开始有计划地摧毁反抗军占领的星球。由于星球的不断被摧毁，两个星球之间的通讯通道也开始不可靠起来。现在，反抗军首领交给你一个任务：给出原来两个星球之间的以太隧道连通情况以及帝国打击的星球顺序，以尽量快的速度求出每一次打击之后反抗军占据的星球的连通快的个数。（如果两个星球可以通过现存的以太通道直接或间接地连通，则这两个星球在同一个连通块中）。

Input

输入文件第一行包含两个整数，N (1 <= N <= 2M) 和M (1 <= M <= 200,000)，分别表示星球的数目和以太隧道的数目。星球用0~N-1的整数编号。接下来的M行，每行包括两个整数X, Y，其中（0<=X<>Y

Output

输出文件的第一行是开始时星球的连通块个数。接下来的N行，每行一个整数，表示经过该次打击后现存星球的连通块个数。

Sample Input

8 13
0 1
1 6
6 5
5 0
0 6
1 2
2 3
3 4
4 5
7 1
7 2
7 6
3 6
5
1
6
3
5
7

Sample Output

1
1
1
2
3
3

HINT

 

Source

 题解：正如JSZKC神犇所言——既然并查集不能合并，那么倒着插入不就行了？于是乎我这么做了一下，结果是70分，TLE。。。然后我只好找网上的标程，结果发现了人家在并查集里面有个异常强悍的优化（具体见程序里面的getfat函数），然后就擦着边AC了。。。具体做法是——先把所有边里面没有涉及到被删除点的全部合并，然后按照删点顺序倒着来合并，这一路每次要记录下连通块数量。。。（注意：最后输出时要-i+1，因为假如举个例子，所有的星球在最后的数据中都被干掉了的话，那么假如单纯是连通块的话，应该有N个才是，可是事实上一个星球都没了。。。）

 

type point=^node;
     node=record
                g:longint;
                next:point;
     end;
var
   i,j,k,l,m,n,t:longint;
   a:array[0..400000] of point;
   c,b,d,e:array[0..400000] of longint;
   p:point;
function getfat(x:longint):longint;inline;
         begin
              if x<>c[x] then
                 begin
                      c[x]:=getfat(c[x]);  //orz强悍的优化
                 end;
              exit(c[x]);
         end;
function tog(x,y:longint):boolean;inline;
         begin
              exit(getfat(x)=getfat(y));
         end;
procedure merge(x,y:longint);inline;
          begin
               c[getfat(x)]:=getfat(y);
          end;
procedure add(x,y:longint);inline;
          var p:point;
          begin
               new(p);
               p^.g:=y;
               p^.next:=a[x];
               a[x]:=p;
          end;
begin
     readln(n,m);
     for i:=1 to n do
         begin
              c[i]:=i;
              a[i]:=nil;
         end;
     for i:=1 to m do
         begin
              readln(j,k);
              add(j+1,k+1);add(k+1,j+1);
         end;
     fillchar(b,sizeof(b),0);
     readln(t);
     for i:=1 to t do
         begin
              readln(d[i]);
              d[i]:=d[i]+1;
              b[d[i]]:=1;
         end;
     l:=n;
     for i:=1 to n do
         begin
              if b[i]=0 then
                 begin
                      p:=a[i];
                      while p<>nil do
                            begin
                                 if b[p^.g]=0 then
                                    begin
                                         if not(tog(i,p^.g)) then
                                            begin
                                                 dec(l);merge(i,p^.g);
                                            end;
                                    end;
                                 p:=p^.next;
                            end;
                 end;
         end;
     e[t+1]:=l;
     for i:=t downto 1 do
         begin
              b[d[i]]:=0;
              p:=a[d[i]];
              while p<>nil do
                    begin
                         if b[p^.g]=0 then
                            begin
                                 if not(tog(d[i],p^.g)) then
                                    begin
                                         merge(d[i],p^.g);
                                         dec(l);
                                    end;
                            end;
                         p:=p^.next;
                    end;
              e[i]:=l;
         end;
     for i:=1 to t+1 do writeln(e[i]-i+1);
end.