Delphi类引用示例

相关资料：

https://jingyan.baidu.com/article/bad08e1e2ec23b09c9512148.html

实例代码：

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;

type
  TControlClass = class of TControl;

  TForm1 = class(TForm)
    RadioGroup1: TRadioGroup;
    procedure FormCreate(Sender: TObject);
    procedure RadioGroup1Click(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
var
  CtlClassRef: TControlClass;

procedure TForm1.FormCreate(Sender: TObject);
begin
  RadioGroup1.Width := 400;
  RadioGroup1.Columns := 3;
  RadioGroup1.Items.Add('Button');
  RadioGroup1.Items.Add('Edit');
  RadioGroup1.Items.Add('Checkbox');
  RadioGroup1.ItemIndex := 0;
  CtlClassRef := TButton;
end;

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  NewCtrl: TControl;
begin
  NewCtrl := CtlClassRef.Create(Self);
  NewCtrl.Name := CtlClassRef.ClassName + IntToStr(Self.ControlCount);
  NewCtrl.Parent := Self;
  NewCtrl.Left := X;
  NewCtrl.Top := Y;
end;

procedure TForm1.RadioGroup1Click(Sender: TObject);
begin
  case RadioGroup1.ItemIndex of
    0: CtlClassRef := TButton;
    1: CtlClassRef := TEdit;
    2: CtlClassRef := TCheckBox;
  end;
end;

end.