【网络流24题】 最长递增子序列问题

（题目复制自洛谷）

题目描述

给定正整数序列x1,...,xn 。

（1）计算其最长递增子序列的长度s。

（2）计算从给定的序列中最多可取出多少个长度为s的递增子序列。

（3）如果允许在取出的序列中多次使用x1和xn，则从给定序列中最多可取出多少个长度为s的递增子序列。

编程任务：

设计有效算法完成（1）（2）（3）提出的计算任务。

输入输出格式

输入格式：

第1 行有1个正整数n，表示给定序列的长度。接下来的1 行有n个正整数n:x1, ..., xn。

 

输出格式：

第1 行是最长递增子序列的长度s。第2行是可取出的长度为s 的递增子序列个数。第3行是允许在取出的序列中多次使用x1和xn时可取出的长度为s 的递增子序列个数。

输入输出样例

输入样例#1：

4
3 6 2 5

输出样例#1：

2
2
3


  以前做过，再复习一下网络流。

program alis(input,output);
const
  inf=123456789;
type
  etype=record
     t,c,next,rev:longint;
  end;
var
  a,d,cur:array[-550..550]of longint;
  e:array[0..1000010]of etype;
  f,x:array[0..500]of longint;
  q:array[0..1010]of longint;
  n,i,j,ans,h,t,cnt,r:longint;
function max(a,b:longint):longint;
begin
   if a>b then exit(a) else exit(b);
end;
function min(a,b:longint):longint;
begin
   if a<b then exit(a) else exit(b);
end;
procedure ins(x,y,c:longint);
begin
   inc(cnt);e[cnt].t:=y;e[cnt].c:=c;e[cnt].next:=a[x];a[x]:=cnt;
end;
procedure add(x,y,c:longint);
begin
   ins(x,y,c);e[cnt].rev:=cnt+1;ins(y,x,0);e[cnt].rev:=cnt-1;
end;
procedure bfs;
begin
   for i:=-n to n+1 do d[i]:=-1;
   h:=0;t:=1;q[1]:=0;d[0]:=0;
   while h<t do
      begin
         inc(h);i:=a[q[h]];
         while i<>0 do
            begin
               if (e[i].c>0) and (d[e[i].t]=-1) then
                  begin
                     d[e[i].t]:=d[q[h]]+1;
                     inc(t);q[t]:=e[i].t;
                  end;
               i:=e[i].next;
            end;
      end;
end;
function dfs(k,f:longint):longint;
var
  ans,r,i:longint;
begin
   if (k=n+1) or (f=0) then exit(f);
   ans:=0;i:=cur[k];
   while i<>0 do
      begin
         if (d[e[i].t]=d[k]+1) and (e[i].c>0) then
            begin
               r:=dfs(e[i].t,min(f,e[i].c));
               dec(e[i].c,r);inc(e[e[i].rev].c,r);
               inc(ans,r);dec(f,r);
               if f=0 then break;
            end;
         i:=e[i].next;
         cur[k]:=i;
      end;
   if f>0 then d[k]:=-1;
   exit(ans);
end;
function maxflow:longint;
var
  ans:longint;
begin
   ans:=0;
   while true do
      begin
         bfs;
         if d[n+1]=-1 then break;
         for i:=-n to n+1 do cur[i]:=a[i];
         ans:=ans+dfs(0,inf);
      end;
   exit(ans);
end;
begin
   assign(input,'alis.in');assign(output,'alis.out');reset(input);rewrite(output);
   readln(n);
   for i:=1 to n do read(x[i]);
   ans:=0;
   for i:=1 to n do
      begin
         f[i]:=1;
         for j:=1 to i-1 do
            if x[j]<=x[i] then f[i]:=max(f[i],f[j]+1);
         ans:=max(ans,f[i]);
      end;
   writeln(ans);
   fillchar(a,sizeof(a),0);cnt:=0;
   for i:=1 to n do add(-i,i,1);
   for i:=1 to n do if f[i]=1 then add(0,-i,1);
   for i:=2 to n do for j:=1 to i-1 do if (f[i]=f[j]+1) and (x[j]<=x[i]) then add(j,-i,1);
   for i:=1 to n do if f[i]=ans then add(i,n+1,1);
   r:=maxflow;writeln(r);
   add(0,1,inf);if f[n]=ans then add(-n,n+1,inf);
   writeln(r+maxflow);
   close(input);close(output);
end.