基本函数（4）——Power Query M语言

基本函数（4）

数字与文本的转换（Number与Text值的转换）

Number.From、Number.FromText、Number.ToText、Number.IsOdd、Number.IsEven

• Number.From

• Number.FromText

• Number.ToText

• Number.IsOdd

• Number.IsEven

Number.ToText

等价于format，某些情况可做正负零判断代替IF

https://docs.microsoft.com/zh-cn/dax/format-function-dax

实例1：添加库存状态列

 M code:

let
    源 = Excel.CurrentWorkbook(){[Name="表1"]}[Content],
    更改的类型 = Table.TransformColumnTypes(源,{{"日期", type date}}),
    已添加自定义 = Table.AddColumn(更改的类型, "库", each Number.ToText([进出],"入库;出库;"))
in
    已添加自定义

实例2：工资条

 M code:

let
    源 = Excel.CurrentWorkbook(){[Name="表4"]}[Content],
    a = List.Select(Table.ToRecords(源),each _[姓名]<>null),
    b = Table.FromRecords(List.Transform(List.Select(List.Positions(a),each Number.IsEven(_)),each a{_}))
in
    b

数字的取舍之道（Round系列函数）

Number.RoundUp、Number.RoundDown、Number.RoundTowardZero、Number.RoundAwayFromZero、Number.Round

• Number.RoundUp 向值大的方向入
• Number.RoundDown 向值小的方向舍
• Number.RoundTowardZero 靠近0入
• Number.RoundAwayFromZero 远离0舍
• Number.Round 四舍五入

 实例：制作标签

 

 M code:

let
    源 = Excel.CurrentWorkbook(){[Name="表4"]}[Content],
    a = List.Transform(Table.ToRecords(源),each  Table.Transpose(Table.DemoteHeaders(Table.FromRecords({_&[#""=null],[考号=null,姓名=null,#""=null]})))),
    b = List.Transform({0..Number.RoundDown(List.Count(a)/4)},each Table.Transpose(Table.Combine(List.Range(a,_*4,4)))),
    自定义1 = Table.Combine(b)
in
    自定义1

绝对力量不多余

Number.Abs、Number.Power、Number.Mod、Number.IntegerDivide

• Number.Abs(数字)
• Number.Power(底数,指数
• Number.Mod(被除数,除数)
• Number.IntegerDivide(被除数,除数)

 实例：单列转多行多列

 

M code:

let
    源 = Excel.CurrentWorkbook(){[Name="表6"]}[Content][姓名],
    a = List.Transform({0.. Number.IntegerDivide(List.Count(源)/4,1)},each List.Range(源,_*4,4)),
    b = Table.Transpose(Table.FromColumns(a))
in
   b

随机不随意

Number. Random、Number.RandomBetween

实例：随机抽题系统制作

 M code:

let
    源 = Excel.CurrentWorkbook(){[Name="表1"]}[Content][选择题],
    a = List.Range(List.Sort({0..List.Count(源)/5-1},each Number.Random()),0,20),
    b = List.Transform(a,each List.Range(源,_*5,5)),
    自定义1 = Table.FromColumns({List.Combine(b)},{"选择题"}),
    已添加索引 = Table.AddIndexColumn(自定义1, "索引", 1, 1),
    已添加自定义 = Table.AddColumn(已添加索引, "序号", each if Number.Mod(([索引]+4)/5,1)=0 then ([索引]+4)/5 else ""),
    删除的列 = Table.RemoveColumns(已添加自定义,{"索引"}),
    重排序的列 = Table.ReorderColumns(删除的列,{"序号", "选择题"})
in
    重排序的列

注意：利用List.Sort({ }, each Number.Random)可以将原有序列随机打乱顺序

a = List.Range(List.Sort({0..List.Count(源)/5-1},each Number.Random()),0,20),

End