【CF739B】Alyona and a tree（树上差分，二分，树形DP）

题意：给出一棵有根树，树上每个点、每条边都有一个权值。

现在给出“控制”的定义：对一个点u，设点v在其子树上，且dis(u,v)≤av，则称u控制v。

要求求出每个点控制了多少个点

n (1 ≤ n ≤ 2·105).  (1 ≤ ai ≤ 109) 1 ≤ pi ≤ n, 1 ≤ wi ≤ 109) 

思路：在学校CF有时上不去不知道为什么

对于确定的点i，计算它对哪些点有贡献

dis[i]-dis[u]<=a[i]

dis[u]<=a[i]-dis[i]满足二分性

倍增枚举深度最小的i能给它贡献的点j

树上差分部分就是 inc(fa[i]) dec(fa[j])

最后统计出来的答案就是它子树里的和

注意INT64

var f:array[0..210000,0..19]of longint;
    head,vet,next,len,flag,a:array[0..410000]of longint;
    dp,dep,dis:array[0..410000]of int64;
    n,tot,i,x,y,l,r,mid,last,j:longint;
 
procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;
 
procedure dfs(u:longint);
var e,v,i:longint;
begin
 flag[u]:=1;
 for i:=1 to 19 do
 begin
  if dep[u]<(1<<i) then break;
  f[u,i]:=f[f[u,i-1],i-1];
 end;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   dep[v]:=dep[u]+1;
   dis[v]:=dis[u]+len[e];
   f[v,0]:=u;
   dfs(v);
  end;
  e:=next[e];
 end;
end;
 
procedure dfs2(u:longint);
var e,v:longint;
begin
 flag[u]:=1;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   dfs2(v);
   dp[u]:=dp[u]+dp[v];
  end;
  e:=next[e];
 end;
end;
 
function clac(x,y:longint):longint;
var i:longint;
begin
 for i:=0 to 19 do
  if y and (1<<i)>0 then x:=f[x,i];
 exit(x);
end;
 
begin
 //assign(input,'cf739B.in'); reset(input);
 //assign(output,'cf739B.out'); rewrite(output);
 readln(n);
 for i:=1 to n do read(a[i]);
 for i:=2 to n do
 begin
  readln(x,y);
  add(i,x,y);
  add(x,i,y);
 end;
 dfs(1);
 fillchar(flag,sizeof(flag),0);
 for i:=1 to n do
 begin
  l:=1; r:=dep[i]; last:=i;
  while l<=r do
  begin
   mid:=(l+r)>>1;
   j:=clac(i,mid);
   if dis[i]-dis[j]<=a[i] then begin last:=j; l:=mid+1; end
    else r:=mid-1;
  end;
  dec(dp[f[last,0]]);
  inc(dp[f[i,0]]);
 end;
 
 dfs2(1);
 for i:=1 to n-1 do write(dp[i],' ');
 write(dp[n]);
 //close(input);
 //close(output);
end.