QTP自传之测试报告

前言

测试报告是测试阶段的最后产出，也是最重要的产出，自动化测试报告也是如此。前期所做的工作，添加对象、编写脚本等都是为了可以生成一份正确、严谨的测试报告。我作为一款功能全面的自动化测试工具，毫无疑问，提供了强大的测试报告定制功能，让我们从对象库编程中的脚本说起吧,脚本代码如下。

With Browser("web对象演示")
With .Page("web对象演示")
        .WebEdit("用户名").Set "test"
        .WebEdit("邮箱").Set "11111@qq.com"
        .WebEdit("个人介绍").Set "haha"
        .WebList("开发语言").Select "java"
        .WebCheckBox("电影").Set "ON"
        .WebCheckBox("游戏").Set "ON"
        .WebRadioGroup("性别").Select "男"
        .WebButton("提交").Click
End With

With .Page("用户信息示")
        username=.WebTable("用户名").GetCellData(2,1)
        mail=.WebTable("用户名").GetCellData(2,2)
        sex=.WebTable("用户名").GetCellData(2,3)
End With
End With
If username="test" and mail="11111@qq.com" and sex="男" Then
   msgbox "OK"
End If

为了方便的看出测试报告的效果，简单的修改验证部分代码如下，将mail的验证数据故意写错为"22222@qq.com"。

If username="test" Then
    print "OK"
else
    print "NOT OK"
End If
If mail="22222@qq.com" Then '这里故意把验证数据写错，运行结果应该是Failed
    print "OK"
else
    print "NOT OK"
End If
If sex="男" Then
    print "OK"
else
    print "NOT OK"
End If

脚本运行后，点击【Automation】->【Results】打开测试结果。

可以看到Passed、Failed部分都为0，也就是说并没有把刚才if语句的判断结果加入到测试报告中，那是由于没有采用Report对象生成测试报告，再次修改验证部分代码，运行后看结果。

If username="test" Then
    reporter.ReportEvent micPass,"用户名","预期结果:test"&"||"&"实际结果:"&username
    else
    reporter.ReportEvent micFail,"用户名","预期结果:test"&"||"&"实际结果:"&username
End If
If mail="22222@qq.com" Then '这里测试结果应该是Failed
    reporter.ReportEvent micPass,"邮箱","预期结果:22222@qq.com"&"||"&"实际结果:"&mail
    else
    reporter.ReportEvent micFail,"邮箱","预期结果:22222@qq.com"&"||"&"实际结果:"&mail
End If
If sex="男" Then
    reporter.ReportEvent micPass,"性别","预期结果:男"&"||"&"实际结果:"&sex
    else
    reporter.ReportEvent micFail,"性别","预期结果:男"&"||"&"实际结果:"&sex
End If

Reporter对象

这次成功了，2Passed，1Failed和我们想要的一样，Reporter对象是大功臣，必须要隆重的向大家介绍。在关键字视图中查看Reporter对象，发现有2个方法和3个属性可以使用，关于这些属性方法的具体介绍可以按F1自行查看，这里主要介绍一下ReportEvent方法。

Reporter.ReportEvent EventStatus, ReportStepName, Details [, ImageFilePath]这是ReportEvent方法的参数介绍。

• EventStatus：测试结果状态，有micPass、micFail、micDone和micWarning四个值可供选择，按字面意思理解即可。

• ReportStepName：在测试结果中显示的步骤名称。

• Details：详细描述。

• ImageFilePath：可选参数，截图路径。

reporter.ReportEvent micFail,"邮箱","预期结果:22222@qq.com"&"||"&"实际结果:"&mail，代表的意思是如果邮箱值与预期值不相等则将结果记为失败，步骤名称为“邮箱”，如下图

但是，使用ReportEvent方法生成的测试报告都是一个层级的，在同一节点上，看上没有层次感。如果我们想把邮箱的验证结果放在用户名下面，而把性别的验证结果放在邮箱下面，像这样（用户名验证失败是因为父节点的结果是所有子节点结果的合取，子节点有一个失败，父节点就失败）。

这就需要用到Reporter对象的隐藏方法了，先上代码

If username="test" Then
    reporter_set micPass,"用户名","test",username
    else
    reporter_set micFail,"用户名","test",username
End If
If mail="22222@qq.com" Then '这里测试结果应该是Failed
    reporter_set micPass,"邮箱","22222@qq.com",mail
    else
    reporter_set micFail,"邮箱","22222@qq.com",mail
End If
If sex="男" Then
    reporter_set micPass,"性别","男",sex
    else
    reporter_set micFail,"性别","男",sex
End If

Private function reporter_set(ss,node_step,exp_value,actul_value)
'定义字典对象
Set result_desc = CreateObject("Scripting.Dictionary")
'状态
result_desc("Status")=ss
'设置节点名称
result_desc("PlainTextNodeName")=node_step
' 详细描述信息,可以使用HTML格式
result_desc("StepHtmlInfo") = "预期结果:"&exp_value&"||"&"实际结果:"&actul_value
'  使用Reporter对象的LogEvent方法写入新节点
int_id= Reporter.LogEvent("User", result_desc, Reporter.GetContext) 
' 调用Reporter对象的SetContext把新写入的节点作为父节点
Reporter.SetContext int_id

End Function

Reporter对象的LogEvent方法可以写入一个新的节点，SetContext 是将新写入的节点当作父节点，如果想把邮箱和性别都作为用户名的子节点，需要调用Reporter对象的UnSetContext方法，该方法返回上一层节点。

'返回上一层节点演示
If username="test" Then
    reporter_set micPass,"用户名","test",username
    else
    reporter_set micFail,"用户名","test",username
End If
If mail="22222@qq.com" Then '这里测试结果应该是Failed
    reporter_set micPass,"邮箱","22222@qq.com",mail
    else
    reporter_set micFail,"邮箱","22222@qq.com",mail
    return_previous_node
End If
If sex="男" Then
    reporter_set micPass,"性别","男",sex
    else
    reporter_set micFail,"性别","男",sex
End If

Private function reporter_set(ss,node_step,exp_value,actul_value)
'定义字典对象
Set result_desc = CreateObject("Scripting.Dictionary")
'状态
result_desc("Status")=ss
'设置节点名称
result_desc("PlainTextNodeName")=node_step
' 详细描述信息,可以使用HTML格式
result_desc("StepHtmlInfo") = "预期结果:"&exp_value&"||"&"实际结果:"&actul_value
'  使用Reporter对象的LogEvent方法写入新节点
intId = Reporter.LogEvent("User", result_desc, Reporter.GetContext) 
' 调用Reporter对象的SetContext把新写入的节点作为父节点
Reporter.SetContext intId
End Function

Function return_previous_node
Reporter.UnSetContext
End Function

关于Reporter对象就介绍这么多了，他还有很多隐藏的方法，有兴趣的话可以研究研究，下一次将介绍EOM方面的内容。