1040: [ZJOI2008]骑士

Description

Z国的骑士团是一个很有势力的组织，帮会中汇聚了来自各地的精英。他们劫富济贫，惩恶扬善，受到社会各界的赞扬。最近发生了一件可怕的事情，邪恶的Y国发动了一场针对Z国的侵略战争。战火绵延五百里，在和平环境中安逸了数百年的Z国又怎能抵挡的住Y国的军队。于是人们把所有的希望都寄托在了骑士团的身上，就像期待有一个真龙天子的降生，带领正义打败邪恶。骑士团是肯定具有打败邪恶势力的能力的，但是骑士们互相之间往往有一些矛盾。每个骑士都有且仅有一个自己最厌恶的骑士（当然不是他自己），他是绝对不会与自己最厌恶的人一同出征的。战火绵延，人民生灵涂炭，组织起一个骑士军团加入战斗刻不容缓！国王交给了你一个艰巨的任务，从所有的骑士中选出一个骑士军团，使得军团内没有矛盾的两人（不存在一个骑士与他最痛恨的人一同被选入骑士军团的情况），并且，使得这支骑士军团最具有战斗力。为了描述战斗力，我们将骑士按照1至N编号，给每名骑士一个战斗力的估计，一个军团的战斗力为所有骑士的战斗力总和。
Input

第一行包含一个正整数N，描述骑士团的人数。接下来N行，每行两个正整数，按顺序描述每一名骑士的战斗力和他最痛恨的骑士。
Output

应包含一行，包含一个整数，表示你所选出的骑士军团的战斗力。
Sample Input
3
10 2
20 3
30 1
Sample Output
30
【数据规模】
对于30%的测试数据，满足N ≤ 10；
对于60%的测试数据，满足N ≤ 100；
对于80%的测试数据，满足N ≤ 10 000。
对于100%的测试数据，满足N ≤ 1 000 000，每名骑士的战斗力都是不大于 1 000 000的正整数。

一个图分为几个联通块，每个块有且只有一个环，求最大点权独立集（是这样说的吗，我瞎编的.......）

先用tarjan求出一个环上的两点，然后分为两种情况树dp

一是A不选，二是B不选，两者选最优（不选但是不要直接把点删掉，因为删掉可能会把这个联通块分成几部分，所以dp时只要把它被选的情况的最优值减去它的权值就行了）

const
    maxn=1000010;
var
    first,next,last,cut:array[0..maxn*2]of longint;
    f:array[0..maxn,0..1]of int64;
    node,flag,a,dfn:array[0..maxn]of longint;
    n,tot,num,time,d:longint;
    ans:int64;
 
procedure insert(x,y:longint);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
end;
 
procedure dfs(x:longint);
var
    i:longint;
begin
    flag[x]:=time;
    inc(d);
    dfn[x]:=d;
    i:=first[x];
    while i<>0 do
      begin
        if cut[i]<>time then
        begin
          if flag[last[i]]<>time then
            begin
              cut[i xor 1]:=time;
              dfs(last[i]);
            end
          else
            if dfn[last[i]]<dfn[x] then
            begin
              inc(num);
              node[num]:=x;
              inc(num);
              node[num]:=last[i];
            end;
        end;
        i:=next[i];
      end;
end;
 
procedure init;
var
    i,x:longint;
begin
    read(n);
    tot:=1;
    for i:=1 to n do
      begin
        read(a[i],x);
        insert(i,x);
        insert(x,i);
      end;
    inc(time);
    for i:=1 to n do
      if flag[i]<>time then dfs(i);
end;
 
function max(x,y:int64):int64;
begin
    if x>y then exit(x);
    exit(y);
end;
 
procedure dp(x:longint);
var
    i:longint;
begin
    flag[x]:=time;
    f[x,1]:=a[x];
    f[x,0]:=0;
    i:=first[x];
    while i<>0 do
      begin
        if flag[last[i]]<>time then
        begin
          dp(last[i]);
          inc(f[x,1],f[last[i],0]);
          inc(f[x,0],max(f[last[i],1],f[last[i],0]));
        end;
        i:=next[i];
      end;
end;
 
procedure work;
var
    i:longint;
    sum:int64;
begin
    for i:=1 to num>>1 do
      begin
        inc(time);
        dp(node[i<<1]);
        sum:=max(f[node[i<<1],1]-a[node[i<<1]],f[node[i<<1],0]);
        inc(time);
        dp(node[i<<1-1]);
        sum:=max(sum,max(f[node[i<<1-1],1]-a[node[i<<1-1]],f[node[i<<1-1],0]));
        inc(ans,sum);
      end;
    write(ans);
end;
 
begin
    init;
    work;
end.