1030: [JSOI2007]文本生成器

Description

JSOI交给队员ZYX一个任务，编制一个称之为“文本生成器”的电脑软件：该软件的使用者是一些低幼人群，他们现在使用的是GW文本生成器v6版。该软件可以随机生成一些文章―――总是生成一篇长度固定且完全随机的文章—— 也就是说，生成的文章中每个字节都是完全随机的。如果一篇文章中至少包含使用者们了解的一个单词，那么我们说这篇文章是可读的（我们称文章a包含单词b，当且仅当单词b是文章a的子串）。但是，即使按照这样的标准，使用者现在使用的GW文本生成器v6版所生成的文章也是几乎完全不可读的。 ZYX需要指出GW文本生成器 v6生成的所有文本中可读文本的数量，以便能够成功获得v7更新版。你能帮助他吗？
Input

输入文件的第一行包含两个正整数，分别是使用者了解的单词总数N (<= 60)，GW文本生成器 v6生成的文本固定长度M；以下N行，每一行包含一个使用者了解的单词。 这里所有单词及文本的长度不会超过100，并且只可能包含英文大写字母A..Z　 。
Output

一个整数，表示可能的文章总数。只需要知道结果模10007的值。
Sample Input
2 2
A
B

Sample Output
100

在AC自动机上的dp

f[i,j,k]表示长度为i，在节点j，状态为k的方案数（k=0时为不匹配，k=1时为匹配）

const
    maxn=6010;
    maxm=105;
    h=10007;
type
    node=record
      fail:integer;
      flag:boolean;
      go:array['A'..'Z']of integer;
    end;
var
    tree:array[0..maxn]of node;
    f:array[0..maxn,0..maxn,0..1]of integer;
    n,m,tot:longint;
    s:string;

procedure insert;
var
    i,j:longint;
begin
    readln(s);
    j:=0;
    for i:=1 to length(s) do
      begin
        if tree[j].go[s[i]]=0 then
        begin
          inc(tot);
          tree[j].go[s[i]]:=tot;
        end;
        j:=tree[j].go[s[i]];
      end;
    tree[j].flag:=true;
end;

var
    q:array[0..maxn]of longint;
    head,tail:longint;

procedure build;
var
    i:char;
    k:longint;
begin
    head:=1;
    tail:=1;
    q[1]:=0;
    while head<=tail do
      begin
        for i:='A' to 'Z' do
          if tree[q[head]].go[i]<>0 then
          begin
            inc(tail);
            q[tail]:=tree[q[head]].go[i];
            k:=tree[q[head]].fail;
            if k<>q[head] then
            begin
              while (k<>0) and (tree[k].go[i]=0) do
                k:=tree[k].fail;
              tree[q[tail]].fail:=tree[k].go[i];
            end;
          end;
        for i:='A' to 'Z' do
          if tree[q[head]].go[i]=0 then tree[q[head]].go[i]:=tree[tree[q[head]].fail].go[i];
        if tree[tree[q[head]].fail].flag then tree[q[head]].flag:=true;
        inc(head);
      end;
end;

procedure init;
var
    i:longint;
begin
    readln(n,m);
    for i:=1 to n do
      insert;
    build;
end;

procedure work;
var
    i,j,ans:longint;
    s:char;
begin
    for s:='A' to 'Z' do
      if tree[tree[0].go[s]].flag then inc(f[1,tree[0].go[s],1])
      else inc(f[1,tree[0].go[s],0]);
    for i:=1 to m-1 do
      for j:=0 to tot do
        for s:='A' to 'Z' do
          if tree[tree[j].go[s]].flag then f[i+1,tree[j].go[s],1]:=(f[i+1,tree[j].go[s],1]+f[i,j,0]+f[i,j,1])mod h
          else
            begin
              f[i+1,tree[j].go[s],1]:=(f[i+1,tree[j].go[s],1]+f[i,j,1])mod h;
              f[i+1,tree[j].go[s],0]:=(f[i+1,tree[j].go[s],0]+f[i,j,0])mod h;
            end;
    ans:=0;
    for i:=0 to tot do
      ans:=(ans+f[m,i,1])mod h;
    writeln(ans);
end;

begin
    init;
    work;
end.